튜토리얼

ASP 개발환경에서 바로써트 SDK를 추가하여 전자서명 요청(requestSign) 함수를 구현하는 예시입니다.

1. BaroCert SDK 추가 및 설정

① ASP SDK 예제코드 다운로드 후 압축을 해제합니다.

② 압축해제한 SDK 예제코드에 포함된 Barocert/ 폴더를 웹사이트 Root Directory 경로에 복사합니다.

③ 서비스 연동환경 설정을 위해 프로젝트 KakaocertExample 폴더에 common.asp 파일을 생성하고 아래의 코드를 참고하여 인증정보를 설정합니다.

' 링크아이디 
Dim LinkID : LinkID = "TESTER"

' 비밀키
Dim SecretKey : SecretKey = "SwWxqU+0TErBXy/9TVjIPEnI0VTUMMSQZtJf3Ed8q3I="

Dim m_KakaocertService : set m_KakaocertService = New KakaocertService

' Kakaocert 서비스 모듈 초기화
m_KakaocertService.Initialize LinkID, SecretKey

' 인증토큰 IP 검증 설정, ture-사용, false-미사용, (기본값:true)
m_KakaocertService.IPRestrictOnOff = True

' 통신 고정 IP, true-사용, false-미사용, (기본값:false)
m_KakaocertService.useStaticIP = False

2. RequestSign 기능 구현

프로젝트 Root Directory에 함수 호출을 처리하는 파일을 생성하고, 아래의 코드를 참조하여 코드를 추가합니다.

<html xmlns="http://www.w3.org/1999/xhtml">
	<head>
		<meta http-equiv="Content-Type" content="text/html; charset=euc-kr" />
		<link rel="stylesheet" type="text/css" href="/Example.css" media="screen" />
		<title>Barocert SDK ASP Example.</title>
	</head>
<!--#include file="common.asp"--> 

<%
	'**************************************************************
	' 카카오톡 이용자에게 단건(1건) 문서의 전자서명을 요청합니다.
	' https://developers.barocert.com/reference/kakao/asp/sign/api-single#RequestSign
	'**************************************************************

	' 이용기관코드 (파트너 사이트에서 확인가능)
	Dim clientCode : clientCode = "023040000001"

	' 전자서명 요청 정보 객체
	Dim reqSign : Set reqSign = new Sign
	' 수신자 휴대폰번호 - 11자 (하이픈 제외)
	reqSign.ReceiverHP = m_KakaocertService.encrypt("01012341234")
	' 수신자 성명 - 80자
	reqSign.ReceiverName = m_KakaocertService.encrypt("홍길동")
	' 수신자 생년월일 - 8자 (yyyyMMdd)
	reqSign.ReceiverBirthday = m_KakaocertService.encrypt("19700101")
	' 서명 요청 제목 - 최대 40자
	reqSign.SignTitle = "전자서명(단건) 서명 요청 제목"
	' 커스텀 메시지 - 최대 500자
	reqSign.ExtraMessage = m_KakaocertService.encrypt("전자서명(단건) 커스텀 메시지")
	' 인증요청 만료시간 - 최대 1,000(초)까지 입력 가능
	reqSign.ExpireIn = 1000
	' 서명 원문 - 원문 2,800자 까지 입력가능
	reqSign.Token = m_KakaocertService.encrypt("전자서명(단건) 요청 원문")
	' 서명 원문 유형
	' TEXT - 일반 텍스트, HASH - HASH 데이터
	reqSign.TokenType = "TEXT"
	' AppToApp 인증요청 여부
	' true - AppToApp 인증방식, false - Talk Message 인증방식
	reqSign.AppUseYN = false
	' App to App 방식 이용시, 호출할 URL
	' reqSign.ReturnURL = "https://www.kakaocert.com"

	On Error Resume Next

		Dim result : Set result = m_KakaocertService.RequestSign(clientCode, reqSign)

		If Err.Number <> 0 then
			Dim code : code = Err.Number
			Dim message : message =  Err.Description
			Err.Clears
		End If

	On Error GoTo 0

%>
	<body>
		<div id="content">
			<p class="heading1">Response</p>
			<br/>
			<fieldset class="fieldset1">
				<legend>카카오 전자서명(단건) 요청</legend>
				<% If code = 0 Then %>
					<ul>
						<li>접수아이디 (ReceiptID) : <%=result.receiptID %></li>
						<li>앱스킴 (Scheme) : <%=result.scheme %></li>
					</ul>
				<% Else %>
					<ul>
						<li>Response.code: <%=code%> </li>
						<li>Response.message: <%=message%> </li>
					</ul>
				<% End If %>
			</fieldset>
		</div>
	</body>
</html>

3. 결과 확인

함수 호출이 정상적으로 처리되면 "채널 메시지 인증" 방식은 접수아이디(32자리 숫자)가 반환되며, "앱투앱 인증" 방식은 접수아이디와 AppScheme 이 함께 반환됩니다. 실패인 경우 BarocertException으로 오류코드("-"로 시작하는 8자리 숫자값)와 오류메시지가 반환됩니다. [오류코드]