튜토리얼

ASP 개발환경에서 바로써트 SDK를 추가하여 본인인증 요청(requestIdentity) 함수를 구현하는 예시입니다.

1. BaroCert SDK 추가 및 설정

① ASP SDK 예제코드 다운로드 후 압축을 해제합니다.

② 압축해제한 SDK 예제코드에 포함된 Barocert/ 폴더를 웹사이트 Root Directory 경로에 복사합니다.

③ 서비스 연동환경 설정을 위해 프로젝트 Root Directory에 common.asp 파일을 생성하고 아래의 코드를 참고하여 API Key를 설정합니다.

' 링크아이디 
Dim LinkID : LinkID = "TESTER"

' 비밀키
Dim SecretKey : SecretKey = "SwWxqU+0TErBXy/9TVjIPEnI0VTUMMSQZtJf3Ed8q3I="

Dim m_NavercertService : set m_NavercertService = New NavercertService

' Navercert 서비스 모듈 초기화
m_NavercertService.Initialize LinkID, SecretKey

' 인증토큰 IP 검증 설정, ture-사용, false-미사용, (기본값:true)
m_NavercertService.IPRestrictOnOff = True

' 통신 고정 IP, true-사용, false-미사용, (기본값:false)
m_NavercertService.useStaticIP = False

2. RequestIdentity 기능 구현

프로젝트 Root Directory에 함수 호출을 처리하는 파일을 생성하고, 아래의 코드를 참조하여 코드를 추가합니다.

<html xmlns="http://www.w3.org/1999/xhtml">
	<head>
		<meta http-equiv="Content-Type" content="text/html; charset=euc-kr" />
		<link rel="stylesheet" type="text/css" href="/Example.css" media="screen" />
		<title>Barocert ASP Example</title>
	</head>
<!--#include file="common.asp"-->

<%
	'**************************************************************
	' 네이버 이용자에게 본인인증을 요청합니다.
	' https://developers.barocert.com/reference/naver/asp/identity/api#RequestIdentity
	'**************************************************************

	' 이용기관코드 (파트너 사이트에서 확인가능)
	Dim clientCode : clientCode = "023090000021"

	' 본인인증 요청 정보 객체
	Dim reqIdentity : Set reqIdentity = new Identity
	' 수신자 휴대폰번호 - 11자 (하이픈 제외)
	reqIdentity.ReceiverHP = m_NavercertService.encrypt("01012341234")
	' 수신자 성명 - 80자
	reqIdentity.ReceiverName = m_NavercertService.encrypt("홍길동")
	' 수신자 생년월일 - 8자 (yyyyMMdd)
	reqIdentity.ReceiverBirthday = m_NavercertService.encrypt("19700101")
	' 고객센터 연락처 - 최대 12자
	reqIdentity.CallCenterNum = "1600-9854"
	' 인증요청 만료시간 - 최대 1,000(초)까지 입력 가능
	reqIdentity.ExpireIn = 1000
	' AppToApp 인증요청 여부
	' true - AppToApp 인증방식, false - 푸시(Push) 인증방식
	reqIdentity.AppUseYN = false

	On Error Resume Next

		Dim result : Set result = m_NavercertService.RequestIdentity(clientCode, reqIdentity)

		If Err.Number <> 0 then
			Dim code : code = Err.Number
			Dim message : message =  Err.Description
			Err.Clears
		End If

	On Error GoTo 0

%>
	<body>
		<div id="content">
			<p class="heading1">Response</p>
			<br/>
			<fieldset class="fieldset1">
				<legend>네이버 본인인증 요청</legend>
				<% If code = 0 Then %>
					<ul>
						<li>접수아이디 (ReceiptID) : <%=result.receiptID %></li>
						<li>앱스킴 (Scheme) : <%=result.scheme %></li>
						<li>앱다운로드URL (MarketURL) : <%=result.marketUrl %></li>
					</ul>
				<% Else %>
					<ul>
						<li>Response.code: <%=code%> </li>
						<li>Response.message: <%=message%> </li>
					</ul>
				<% End If %>
			</fieldset>
		</div>
	</body>
</html>

3. 결과 확인

함수 호출이 정상적으로 처리되면 "푸시(Push) 인증" 방식은 접수아이디(32자리 숫자)가 반환되며, "앱투앱 인증" 방식은 접수아이디와 AppScheme 이 함께 반환됩니다. 실패인 경우 BarocertException으로 오류코드("-"로 시작하는 8자리 숫자값)와 오류메시지가 반환됩니다. [오류코드]